program namethreads;
 
{$mode Delphi}
 
uses
  SysUtils, Classes;

type
  TMyThread = class(TThread)
  private
	i: Integer;
  protected
	procedure Execute; override;
	procedure SetNumber(const aNum: Integer);
  end;
 
procedure TMyThread.Execute;
begin
  writeln('hello from thread '+ThreadID.ToString);
  NameThreadForDebugging(IntToStr(i));
  sleep(30000);
end;
 
procedure TMyThread.SetNumber(const aNum: Integer);
begin
  i := aNum + 1;
end;

var
  threads: TArray<TMyThread>;
  i: Integer;
  thread: TMyThread;
 
begin
  writeln('start');

  SetLength(threads, 5);
  for i := Low(threads) to High(threads) do
  begin
	threads[i] := TMyThread.Create(True);
	threads[i].SetNumber(i);
  end;
 
  for thread in threads do
  begin
	thread.Start;
  end;
 
  sleep(10000);
 
  TMyThread.NameThreadForDebugging('bronze', threads[2].ThreadID); // third thread
  TMyThread.NameThreadForDebugging('always number one'); // main thread
 
  for thread in threads do
  begin
	thread.WaitFor;
  end;
 
  writeln('done');
  readln;
end.

diff --git rtl/win/systhrd.inc rtl/win/systhrd.inc
index 6ab7f8f0b2..ee7e08dbe3 100644
--- rtl/win/systhrd.inc
+++ rtl/win/systhrd.inc
@@ -51,6 +51,16 @@ function  TerminateThread  (threadHandle : THandle; var exitCode : dword) : bool
 function  WaitForSingleObject (hHandle : THandle;Milliseconds: dword): dword; {$ifdef wince}cdecl{$else}stdcall{$endif};external KernelDLL name 'WaitForSingleObject';
 function  WinThreadSetPriority (threadHandle : THandle; Prio: longint): boolean; {$ifdef wince}cdecl{$else}stdcall{$endif};external KernelDLL name 'SetThreadPriority';
 function  WinThreadGetPriority (threadHandle : THandle): LongInt; {$ifdef wince}cdecl{$else}stdcall{$endif};external KernelDLL name 'GetThreadPriority';
+function WinGetCurrentThread: THandle; stdcall; external KernelDLL name 'GetCurrentThread';
+function WinOpenThread(dwDesiredAccess: DWord; bInheritHandle: Boolean; dwThreadId: DWord): THandle; stdcall; external KernelDLL name 'OpenThread';
+function WinIsDebuggerPresent: Boolean; stdcall; external KernelDLL name 'IsDebuggerPresent';
+procedure WinRaiseException(dwExceptionCode, dwExceptionFlags, nNumberOfArguments: DWord; const lpArguments: PUInt64); stdcall; external KernelDLL name 'RaiseException';
+{$ifndef WINCE}
+type
+  TSetThreadDescription = function(threadHandle: THandle; lpThreadDescription: PWideChar): HResult; stdcall;
+var
+  WinSetThreadDescription: TSetThreadDescription;
+{$endif WINCE}
 {$ifndef WINCE}
 function  CreateEvent(lpEventAttributes:pointer;bManualReset:longbool;bInitialState:longbool;lpName:pchar): THandle; stdcall; external KernelDLL name 'CreateEventA';
 function  ResetEvent(hEvent:THandle):LONGBOOL; stdcall; external KernelDLL name 'ResetEvent';
@@ -338,14 +348,71 @@ var
       SysGetCurrentThreadId:=Win32GetCurrentThreadId;
     end;
 
+    { following method is supported on older Windows versions AND currently only supported method by GDB }
+    procedure RaiseMSVCExceptionMethod(threadHandle: TThreadID; const ThreadName: AnsiString);
+    const
+      MS_VC_EXCEPTION: DWord = $406D1388;
+    type
+      THREADNAME_INFO = record
+        dwType: DWord; // Must be 0x1000.
+        szName: PAnsiChar; // Pointer to name (in user addr space).
+        dwThreadID: DWord; // Thread ID (-1=caller thread).
+        dwFlags: DWord; // Reserved for future use, must be zero.
+      end;
+    var
+      thrdinfo: THREADNAME_INFO;
+    begin
+      thrdinfo.dwType:=$1000;
+      thrdinfo.szName:=@ThreadName[1];
+      thrdinfo.dwThreadID:=threadHandle;
+      thrdinfo.dwFlags:=0;
+      try
+        WinRaiseException(MS_VC_EXCEPTION, 0, SizeOf(thrdinfo) div SizeOf(DWord), @thrdinfo);
+      except
+        {do nothing}
+      end;
+    end;
+
+    { following method needs at least Windows 10 version 1607 or Windows Server 2016 }
+    procedure SetThreadDescriptionMethod(threadHandle: TThreadID; const ThreadName: UnicodeString);
+    var
+      thrdhandle: THandle;
+    begin
+      if threadHandle=TThreadID(-1) then
+      begin
+        thrdhandle:=WinGetCurrentThread;
+      end
+      else
+      begin
+        thrdhandle:=WinOpenThread($0400, False, threadHandle);
+      end;
+      WinSetThreadDescription(thrdhandle, @ThreadName[1]);
+    end;
+
     procedure SysSetThreadDebugNameA(threadHandle: TThreadID; const ThreadName: AnsiString);
     begin
-      {$Warning SetThreadDebugNameA needs to be implemented}
+      if WinIsDebuggerPresent then
+      begin
+        RaiseMSVCExceptionMethod(threadHandle, ThreadName);
+      end;
+
+      if Assigned(WinSetThreadDescription) then
+      begin
+        SetThreadDescriptionMethod(threadHandle, UnicodeString(ThreadName));
+      end;
     end;
 
     procedure SysSetThreadDebugNameU(threadHandle: TThreadID; const ThreadName: UnicodeString);
     begin
-      {$Warning SetThreadDebugNameU needs to be implemented}
+      if WinIsDebuggerPresent then
+      begin
+        RaiseMSVCExceptionMethod(threadHandle, AnsiString(ThreadName));
+      end;
+
+      if Assigned(WinSetThreadDescription) then
+      begin
+        SetThreadDescriptionMethod(threadHandle, ThreadName);
+      end;
     end;
 
 {*****************************************************************************
@@ -507,10 +574,10 @@ Var
   WinThreadManager : TThreadManager;
 
 Procedure InitSystemThreads;public name '_FPC_InitSystemThreads';
-{$IFDEF SUPPORT_WIN95}
+{$ifndef WINCE}
 var
   KernelHandle : THandle;
-{$ENDIF SUPPORT_WIN95}
+{$endif}
 begin
   With WinThreadManager do
     begin
@@ -556,6 +623,11 @@ begin
   if IsLibrary then
 {$endif}
     SysInitTLS;
+
+{$ifndef WINCE}
+  KernelHandle:=GetModuleHandle(KernelDLL);
+{$endif}
+
 {$IFDEF SUPPORT_WIN95}
   { Try to find TryEnterCriticalSection function }
   KernelHandle:=GetModuleHandle(KernelDLL);
@@ -564,5 +636,12 @@ begin
   if not assigned(WinTryEnterCriticalSection) then
     WinTryEnterCriticalSection:=@Win95TryEnterCriticalSection;
 {$ENDIF SUPPORT_WIN95}
+
+{$ifndef WINCE}
+  if KernelHandle<>0 then
+  begin
+    WinSetThreadDescription:=TSetThreadDescription(WinGetProcAddress(KernelHandle, 'SetThreadDescription'));
+  end;
+{$endif WINCE}
 end;
 

diff --git rtl/win/sysos.inc rtl/win/sysos.inc
index a85f424900..83a1eda5f1 100644
--- rtl/win/sysos.inc
+++ rtl/win/sysos.inc
@@ -231,6 +231,9 @@ type
    procedure SetLastError(dwErrCode : DWORD);
      {$ifdef wince}cdecl{$else}stdcall{$endif};external KernelDLL name 'SetLastError';
 
+   procedure RaiseException(dwExceptionCode: DWORD; dwExceptionFlags: DWORD; dwArgCount: DWORD; lpArguments: Pointer);
+     {$ifdef wince}cdecl{$else}stdcall{$endif}; external KernelDLL name 'RaiseException';
+
    { time and date functions }
    function GetTickCount : DWORD;
      {$ifdef wince}cdecl{$else}stdcall{$endif};external KernelDLL name 'GetTickCount';
diff --git rtl/win/systhrd.inc rtl/win/systhrd.inc
index ee7e08dbe3..4a929b16d4 100644
--- rtl/win/systhrd.inc
+++ rtl/win/systhrd.inc
@@ -54,7 +54,6 @@ function  WinThreadGetPriority (threadHandle : THandle): LongInt; {$ifdef wince}
 function WinGetCurrentThread: THandle; stdcall; external KernelDLL name 'GetCurrentThread';
 function WinOpenThread(dwDesiredAccess: DWord; bInheritHandle: Boolean; dwThreadId: DWord): THandle; stdcall; external KernelDLL name 'OpenThread';
 function WinIsDebuggerPresent: Boolean; stdcall; external KernelDLL name 'IsDebuggerPresent';
-procedure WinRaiseException(dwExceptionCode, dwExceptionFlags, nNumberOfArguments: DWord; const lpArguments: PUInt64); stdcall; external KernelDLL name 'RaiseException';
 {$ifndef WINCE}
 type
   TSetThreadDescription = function(threadHandle: THandle; lpThreadDescription: PWideChar): HResult; stdcall;
@@ -367,7 +366,7 @@ var
       thrdinfo.dwThreadID:=threadHandle;
       thrdinfo.dwFlags:=0;
       try
-        WinRaiseException(MS_VC_EXCEPTION, 0, SizeOf(thrdinfo) div SizeOf(DWord), @thrdinfo);
+        RaiseException(MS_VC_EXCEPTION, 0, SizeOf(thrdinfo) div SizeOf(DWord), @thrdinfo);
       except
         {do nothing}
       end;
@@ -377,16 +376,25 @@ var
     procedure SetThreadDescriptionMethod(threadHandle: TThreadID; const ThreadName: UnicodeString);
     var
       thrdhandle: THandle;
+      ClosingNeeded: Boolean;
     begin
       if threadHandle=TThreadID(-1) then
       begin
         thrdhandle:=WinGetCurrentThread;
+        ClosingNeeded:=False;
       end
       else
       begin
         thrdhandle:=WinOpenThread($0400, False, threadHandle);
+        ClosingNeeded:=True;
       end;
+
       WinSetThreadDescription(thrdhandle, @ThreadName[1]);
+
+      if ClosingNeeded then
+      begin
+        CloseHandle(thrdhandle);
+      end;
     end;
 
     procedure SysSetThreadDebugNameA(threadHandle: TThreadID; const ThreadName: AnsiString);
@@ -630,7 +638,6 @@ begin
 
 {$IFDEF SUPPORT_WIN95}
   { Try to find TryEnterCriticalSection function }
-  KernelHandle:=GetModuleHandle(KernelDLL);
   if KernelHandle<>0 then
     WinTryEnterCriticalSection:=TTryEnterCriticalSection(WinGetProcAddress(KernelHandle,'TryEnterCriticalSection'));
   if not assigned(WinTryEnterCriticalSection) then
diff --git rtl/win/syswin.inc rtl/win/syswin.inc
index 7204e6797e..e61833a70e 100644
--- rtl/win/syswin.inc
+++ rtl/win/syswin.inc
@@ -130,14 +130,6 @@ type
   TExceptClsProc=function(code: Longint): Pointer; { ExceptClass }
 
 
-procedure RaiseException(
-  dwExceptionCode: DWORD;
-  dwExceptionFlags: DWORD;
-  dwArgCount: DWORD;
-  lpArguments: Pointer);  // msdn: *ULONG_PTR
-  stdcall; external 'kernel32.dll' name 'RaiseException';
-
-
 function RunErrorCode(const rec: TExceptionRecord): longint;
 begin
   { negative result means 'FPU reset required' }